ZMud Aliases and Triggers

Introduction
How to Install
How to Uninstall

Simple
Foundational Aliases



Introduction

These are a few of my simpler and universally useful setups of aliases and triggers. These are ones that I think might have universal appeal, and are relatively easy to install. If anyone has specific requests for custom built aliases and triggers, please let me know.

Disclaimer: All of these are written using ZMud 4.62, which is my preferred version. This is also the version hosted on this site. Some aliases/triggers might not work in other versions of ZMud. I own the other versions, so if you can't figure out how to get them working, I may be able to help. However, as always, I give no guarantees about any of my setups. Don't forget to backup before trying new setups!

How to Install

Installing can be done in two different ways.
1) Copy the entire line written here, then paste it into the command line where you type everything, then just hit [Enter]. Make sure to get the ENTIRE line, even if it's wordwrapped. If you copy just part of it, it won't be very pretty.
2) Click on the Alias or Trigger buttons and copy/paste in the relevant sections. This can be trickier, but it works too.

How to Uninstall

There are also two ways to uninstall.
1) Type in "#unalias <alias name>", or "#untrig {<trigger information>}". #unalias is easier than #untrig.
2) Click on Alias or Triggers and delete them. Remember to look at the very bottom of the trigger list. Anything without a trigger class should be deleted. They are probably broken triggers.

ATCONNECT

ATCONNECT is a very special alias. It's an alias that automatically runs when you connect to the mud. I highly recommend using this alias to disable triggers that you want off by default. You'll use the T-- alias to silently and easily disable the trigger class. Usually you will go in and add any new trigger classes that you want to disable manually. I will have a note at the start of the alias/trigger if it's one that needs to be added to ATCONNECT

eg:
#alias ATCONNECT {T-- SortContainer;T-- SortCombine}


Foundational Aliases/Triggers

These are some base triggers and aliases that my other ones draw from. If you use an alias/trigger from a diff section and it seems to be broken, look in here to see if you need something from here. Please note that #REM doesn't do anything function. Simply a remark.

#alias zc {#REM Selfechoes the spell that you're casting. Very handy esp when spamming.;self zc %1 %2 %3 %4 %5 %6;cast %1 %2 %3 %4 %5 %6}

#alias T- {#REM Deactivate trigger, with echo;#T- %1;#var %1 {};#say %1 Disabled}

#alias T-- {#REM Deactivate trigger, silent;#T- %1;#var %1 {}}

#alias T+ {#REM Activate trigger, with echo;#T+ %1;#var %1 { %1};#say %1 Enabled}

#alias T++ {#REM Activate trigger, silent;#T+ %1;#var %1 { %1}}

#trig {(%d)h(%d)m(%d)v} {#REM Health/mana/vitality monitor. Prompt must include %Hh%Mm%Vv%;#var pHp %1;#var pMa %2;#var pMv %3} Monitor

#trig {^Advantages/Disadvantages:*Magic aptitude} {#var advMagicApt 1} Monitor

#trig {^Advantages/Disadvantages:*Old} {#var advOld 1} Monitor

#trig {^Advantages/Disadvantages:*Toughness} {#var advTough 1} Monitor

#trig {^Age:(%s)(%d) ~((%d) hours~)  Hometown: (%w)} {#var iHours %3} Monitor

#trig {^Base HP: (%d)  Base Mana: (%d)} {#var MaxHp %1;#var MaxMana %2} Monitor

#trig {^Con: (%d) ~((%d)~)  Armor:  P:(%d)  B:(%d)  S:(%d)  M:(%d) G:(%d)} {#var iCon %1;#var ACp %3;#var ACb %4;#var ACs %5;#var ACm %6;#var ACg %7} Monitor

#trig {^Con: (%d) ~(?(%d)~)  Armor:  P:(%d)  B:(%d)  S:(%d)  M:(%d) G:(%d)} {#var iCon %1;#var ACp %3;#var ACb %4;#var ACs %5;#var ACm %6;#var ACg %7} Monitor

#trig {^Exp for level:(%s)(%d)(%s)Exp total: (%d)} {#var iTNL %2} Monitor

#trig {^Exp for level:(%s)-(%d)(%s)Exp total: (%d)} {#var iTNL LEVEL} Monitor

#trig {^Int: (%d) ~((%d)~) } {#var iInt %1} Monitor

#trig {^Int: (%d) ~(?(%d)~) } {#var iInt %1} Monitor

#trig {^Name: (%w)  Level:(%s)(%d)  Sex: (%w)  Race: (%w)} {#var iChar %1;#var iLvl %3;#var iRace %5;#var advMagicApt 0;#var advOld 0;#var advTough 0;#NAME @iChar} Monitor

#trig {^Reconnecting.$} {#REM Check Score & aff for capturing purposes;score;aff} Connect

#trig {^Your last login was } {#REM Check Score & aff for capturing purposes;aff;score} Connect





Disclaimer